refactor: rename modules

Closes #75
2025-06-17 16:32:57 +08:00
parent 6793e90331
commit 71e7993352
79 changed files with 501 additions and 336 deletions
@@ -0,0 +1,110 @@
+/*
+ * Copyright (C) 2024-2025 OnixByte.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+import java.net.URI
+
+plugins {
+    id("java-platform")
+    id("maven-publish")
+    id("signing")
+}
+
+val artefactVersion: String by project
+val projectUrl: String by project
+val projectGithubUrl: String by project
+val licenseName: String by project
+val licenseUrl: String by project
+
+group = "com.onixbyte"
+version = artefactVersion
+
+repositories {
+    mavenCentral()
+}
+
+dependencies {
+    constraints {
+        api("com.onixbyte:devkit-utils:$artefactVersion")
+        api("com.onixbyte:guid:$artefactVersion")
+        api("com.onixbyte:key-pair-loader:$artefactVersion")
+        api("com.onixbyte:num4j:$artefactVersion")
+        api("com.onixbyte:simple-jwt-facade:$artefactVersion")
+        api("com.onixbyte:simple-jwt-authzero:$artefactVersion")
+        api("com.onixbyte:simple-jwt-spring-boot-starter:$artefactVersion")
+    }
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("devkitBom") {
+            groupId = group.toString()
+            artifactId = "devkit-bom"
+            version = artefactVersion
+
+            pom {
+                name = "OnixByte Version Catalogue"
+                description = "OnixByte DevKit BOM is designed to manage dependency versions centrally."
+                url = projectUrl
+
+                licenses {
+                    license {
+                        name = licenseName
+                        url = licenseUrl
+                    }
+                }
+
+                scm {
+                    connection = "scm:git:git://github.com:onixbyte/onixbyte-toolbox.git"
+                    developerConnection = "scm:git:git://github.com:onixbyte/onixbyte-toolbox.git"
+                    url = projectGithubUrl
+                }
+
+                developers {
+                    developer {
+                        id = "zihluwang"
+                        name = "Zihlu Wang"
+                        email = "really@zihlu.wang"
+                        timezone = "Asia/Hong_Kong"
+                    }
+
+                    developer {
+                        id = "siujamo"
+                        name = "Siu Jam'o"
+                        email = "jamo.siu@outlook.com"
+                        timezone = "Asia/Shanghai"
+                    }
+                }
+            }
+
+            from(components["javaPlatform"])
+
+            signing {
+                sign(publishing.publications["devkitBom"])
+            }
+        }
+
+        repositories {
+            maven {
+                name = "sonatypeNexus"
+                url = URI(providers.gradleProperty("repo.maven-central.host").get())
+                credentials {
+                    username = providers.gradleProperty("repo.maven-central.username").get()
+                    password = providers.gradleProperty("repo.maven-central.password").get()
+                }
+            }
+        }
+    }
+}