build: Changed toolchain to gradle.

2024-01-31 02:43:17 +08:00
parent 367a96b9ad
commit 5e31565dd2
25 changed files with 1111 additions and 1001 deletions
@@ -0,0 +1,99 @@
+import java.net.URI
+
+val globalGroupId: String by rootProject.extra
+val globalVersion: String by rootProject.extra
+val projectUrl: String by rootProject.extra
+val projectGithubUrl: String by rootProject.extra
+val licenseName: String by rootProject.extra
+val licenseUrl: String by rootProject.extra
+
+group = globalGroupId
+version = globalVersion
+
+dependencies {
+    implementation(project(":devkit-core"))
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_17
+    targetCompatibility = JavaVersion.VERSION_17
+    withSourcesJar()
+    withJavadocJar()
+}
+
+tasks.test {
+    useJUnitPlatform()
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("devkitUtils") {
+            groupId = globalGroupId
+            artifactId = "devkit-utils"
+            version = globalVersion
+
+            pom {
+                name = "DevKit - Utils"
+                description = "The utils module of JDevKit."
+                url = projectUrl
+
+                licenses {
+                    license {
+                        name = licenseName
+                        url = licenseUrl
+                    }
+                }
+                
+                scm {
+                    connection = "scm:git:git://github.com:CodeCraftersCN/JDevKit.git"
+                    developerConnection = "scm:git:git://github.com:CodeCraftersCN/JDevKit.git"
+                    url = projectGithubUrl
+                }
+
+                developers {
+                    developer {
+                        id = "zihluwang"
+                        name = "Zihlu Wang"
+                        email = "really@zihlu.wang"
+                        timezone = "Asia/Hong_Kong"
+                    }
+                }
+            }
+
+            from(components["java"])
+
+            signing {
+                sign(publishing.publications["devkitUtils"])
+            }
+        }
+
+        repositories {
+            maven {
+                name = "sonatypeNexus"
+                url = URI(providers.gradleProperty("repo.maven-central.host").get())
+                credentials {
+                    username = providers.gradleProperty("repo.maven-central.username").get()
+                    password = providers.gradleProperty("repo.maven-central.password").get()
+                }
+            }
+
+            maven {
+                name = "codingNexus"
+                url = URI(providers.gradleProperty("repo.coding.host").get())
+                credentials {
+                    username = providers.gradleProperty("repo.coding.username").get()
+                    password = providers.gradleProperty("repo.coding.password").get()
+                }
+            }
+
+            maven {
+                name = "githubPackages"
+                url = URI(providers.gradleProperty("repo.github.host").get())
+                credentials {
+                    username = providers.gradleProperty("repo.github.username").get()
+                    password = providers.gradleProperty("repo.github.password").get()
+                }
+            }
+        }
+    }
+}